100 PRINT "}"
110 PRINT "MORTGAGE CALCULATOR by JHS"
120 ? "Revised 10 August 1986":?
130 N=300:NOLD=300:REM 25 YEARS
140 PRINT "ANNUAL PERCENT INTEREST";
149 TRAP 162
150 INPUT I:IF I>0 THEN GOTO 170
160 IF I>0 THEN GOTO 170
161 PRINT "I <=0, SO..."
162 END
170 IF I>=1 THEN GOTO 200
180 I=I*100:? "TIMES 100 ASSUMED"
181 GOSUB 320
200 PRINT "PAYMENT PERIODS/YEAR";
205 TRAP 211
210 INPUT K:GOTO 220
211 ? "MONTHLY PAYMENTS ASSUMED":K=12:GOSUB 320
220 IF K<=0 THEN STOP
230 LET IP=I/(K*100):REM INT/PERIOD
240 PRINT "TOTAL NR OF PAYMENTS";
245 NOLD=N:TRAP 255
250 INPUT N:IF N<=0 THEN STOP
251 GOTO 260
255 N=NOLD:? "ASSUMING N=";:? N:GOSUB 320
260 GOSUB 265:GOTO 270
265 LET R=IP/(1-(1+IP)^-N):RETURN
270 PRINT "MULTIPLIER=";R
279 TRAP 140
280 PRINT "AMOUNT BORROWED";:INPUT A
290 IF A<=0 THEN PRINT :GOTO 140
300 P=INT(A*R*100+0.5)/100:PRINT P
310 GO TO 279
320 SOUND 0,85,10,15:FOR J=1 TO 40:NEXT J:SOUND 0,0,0,0:RETURN
400 REM Print Table of $/1000
410 ? "Starting APR";:INPUT APR1
420 ? " Ending  APR";:INPUT APR2
430 ? " Step in APR";:INPUT ASTEP
432 CLOSE #1:OPEN #1,8,0,"P:"
433 PRINT #1,,"  Dollars Per Thousand Per Month":PRINT #1," "
434 PRINT #1," ","APR","  15 Years","  25 Years","  30 Years":PRINT #1
440 FOR APR=APR1 TO APR2 STEP ASTEP
450 IP=APR/(K*100):N=180:GOSUB 265:R15=R*1000:N=300:GOSUB 265:R25=R*1000
455 N=360:GOSUB 265:R30=R*1000:PRINT #1,,APR,R15,R25,R30
460 NEXT APR