W założeniu MADS skierowany jest do użytkowników QA, XASM, FA. Z QA zapożyczona została składnia, z XASM niektóre makro rozkazy i zmiany składni, z FA obsługa składni Sparta DOS X. Dodatkowo specjalnie z myślą o Lizardzie :) umożliwione zostało użycie dodatkowych znaków w nazwach etykiet. Pozatym dodana została obsługa CPU 6502, 65816, oraz makr, procedur, podziału pamięci na "banki", wielowymiarowych nazw etykiet.

Makro rozkazy XASM'a zastąpione są makrami (plik ..\EXAMPLES\MACROS\XASM.ASM)

MADS jest aplikacją 32 bitową, napisaną w Delphi. Większość asemblerów napisano w C, więc żeby się nie powtarzać użyłem Delphi 7.0 ;)

Wymagany jest DOS 32bit z obsługą długich nazw plików, który spotkamy z Windowsami. Osobiście testowałem program tylko z Windows 2000 i XP.

Procesor, taki aby uciągnął Windows'a :)

Syntax: MADS source [options]

/c              Label case sensitivity
/e              Eat white spaces
/h[:filename]   Header file for CC65
/i:path         Additional include directories
/l[:filename]   Generate listing
/m:filename     File with macro definition
/o:filename     Set object file name
/p              Print fully qualified file names in listing
/s              Silent mode
/t[:filename]   List label table

Domyślne nazwy plików to:

Użycie przełącznika /c spowoduje rozróżnianie wielkości liter w nazwach etykiet, zmiennych, stałych. Dyrektywy assemblera i rozkazy CPU 6502, 65816 są zawsze rozpoznawane bez względu na wielkość liter.

Użycie przełącznika /e spowoduje pomijanie tzw. "białych spacji". Używając tego przełącznika należy pamiętać aby przed komentarzami umieszczać odpowiedni symbol (';','//'), inaczej MADS zacznie analizę komentarza, która najpewniej zakończy się błędem. "Białe spacje" umożliwiają formatowanie listingu, służą jego większej przejrzystości.

Przełącznik /i:path służy do określenia ścieżek poszukiwań dla operacji ICL oraz INS. Przełącznika można użyć wielokrotnie podczas jednego wywołania MADS'a, np.:

 /i:"c:\program files" /i:c:\temp /i:"d:\atari project"

D:\!Delphi\Masm\test.asm (29) ERROR: Missing .EXIT

Teraz wystarczy kliknąć dwukrotnie linię z tym komunikatem, a kursor edytora ustawi się w linii z błędem.

Użycie przełącznika /s spowoduje uaktywnienie tzw. trybu pracy 'Silent mode', czyli żadne komunikaty nie zostaną wyświetlone, co najwyżej komunikaty błędów (ERROR) i ostrzeżenia (WARNING).

Format listingu nie odbiega od tego znanego z XASM, jedyną zmianą jest dodanie przed adresem, numeru banku pamięci. Więcej o bankach w rozdziale "Banki pamięci, definiowanie i odwołania".

Mad-Assembler v0.8 by TeBe/Madteam
Source: D:\!Delphi\Masm\test.asm
     1 				* ---
     2 				; to jest program
     3
     4 = 00,9033		obraz equ $9033
     5 = 00,00A0		scr1 equ $a0
     6
     7 				 opt h-
     8 				 org $2000
     9
    10 00,2000 EA		main nop

Podobnie jak w przypadku XASM, w pliku *.LAB przechowywane są informacje na temat etykiet które wystąpiły w programie.

Specjalne znaczenie w nazwach etykiet mają znaki:

Wartość liczbowa, która występuje po :: oznacza numer wywołania makra.

Mad-Assembler v1.4.2beta by TeBe/Madteam
Label table:
00	0400	@STACK_ADDRESS
00	00FF	@STACK_POINTER
00	2000	MAIN
00	2019	LOOP
00	201C	LOOP::1
00	201C	LHEX
00	0080	LHEX.HLP
00	204C	LHEX.THEX
00	205C	HEX
00	205C	HEX.@GETPAR0.LOOP
00	2079	HEX.@GETPAR1.LOOP

Nie jestem pewien czy wszystko z tym plikiem jest OK, ale Eru chciał żeby coś takiego było więc jest :) Ma on być pomocny przy łączeniu ASM'a z CC65, czyli portem C dla małego Atari. Jego zawartość może wyglądać tak (przykładowy plik TEST.ASM):

#ifndef _TEST_ASM_H_
#define _TEST_ASM_H_

#define TEST_CPU65816 0x200F
#define TEST_CPU6502 0x2017
#define TEST_TEXT6502 0x201F
#define TEST_TEXT65816 0x2024

#endif

W przeciwieństwie do dwu-przebiegowych asemblerów takich jak QA i XASM, MADS jest cztero-przebiegowy. Co to daje ?

 org $00
 
 lda tmp+1
 
tmp lda #$00

Natomiast MADS uprzejmie wygeneruje rozkaz strony zerowej 'lda Z'. I to właściwie główna właściwość czterech biegów.

 org $00
 
 lda.w tmp+1
 
tmp lda #$00

 .b[.z]
 .w[.a][.q]
 .l[.t]

Innym sposobem na wymuszenie rozkazu strony zerowej jest użycie nawiasów klamrowych { } np.

 dta {lda $00},$80    ; lda $80

Dlatego MADS umożliwia takie coś:

 org $20,$3080
 
 lda tmp+1
 
tmp lda #$00

Podsumowując:

 org adres1,adres2

Asembluj od adresu adres1, umieść w pamięci od adresu adres2. Taki ORG zawsze spowoduje stworzenie nowego bloku w pliku.

 label EQU address
 label  =  address
 OPT [chlos][+-]
 ORG [[expression]]address[,address2]
 INS 'filename'["filename"][*][+-value][,+-ofset[,length]]
 ICL 'filename'["filename"]
 DTA [abfghltv](value1,value2...)[(value1,value2...)]
 DTA [cd]'string'["string"]
 RUN adres
 INI adres
 END
 
 SIN(centre,amp,size[,first,last])
 RND(min,max,length)

 :repeat

 BLK N[one] X
 BLK D[os] X
 BLK S[parta] X
 BLK R[eloc] M[ain]|E[xtended]
 BLK E[mpty] X M[ain]|E[xtended]
 BLK U[pdate] S[ymbols]
 BLK U[pdate] A[dress]
 BLK U[pdate] N[ew] X 'string'
 
 label SMB 'string'

 NMB
 RMB
 LMB #value

 .LOCAL
 .ENDL

 .REPT value
 .ENDR

 .IF [IFT] expression
 .ELSE [ELS]
 .ELSEIF [ELI] expression
 .ENDIF [EIF]

 .PRINT 'string1','string2'...,value1,value2,...
 .ERROR [ERT] 'string'["string"] lub .ERROR [ERT] expression

 .MACRO
 .ENDM
 :[%%]parameter

 .EXIT

 .PROC
 .ENDP

 .WORD
 .BYTE
 .LONG
 .DWORD

 .AND
 .OR
 .XOR
 
 .DS 

BLK

 BLK N[one] X                    - blok bez nagłówków, licznik programu ustawiany na X

 BLK D[os] X                     - blok DOS'a z nagłówkiem $FFFF lub bez nagłówka gdy
                                   poprzedni taki sam, licznik programu ustawiany na X

 BLK S[parta] X                  - blok o stałych adresach ładowania z nagłówkiem $FFFA,
                                   licznik programu ustawiany na X

 BLK R[eloc] M[ain]|E[xtended]   - blok relokowalny umieszczany w pamięci main lub extended

 BLK E[mpty] X M[ain]|E[xtended] - blok relokowalny rezerwujący X bajtów w pamięci main lub
                                   extended
                                   Uwaga: licznik programu jest natychmiastowo
                                          zwiększany o X bajtów

 BLK U[pdate] S[ymbols]          - blok aktualizujący w poprzednich blokach SPARTA lub
                                   RELOC adresy symboli SDX

 BLK U[pdate] A[dress]           - blok aktualizacji adresów w blokach RELOC

 BLK U[pdate] N[ew] X 'string'   - blok deklarujący nowy symbol 'string' w bloku RELOC
                                   o adresie X. Gdy nazwa symbolu poprzedzona jest znakiem @,
                                   a adres jest z pamięci podstawowej to taki symbol może być
                                   wywoływany z command.com

Deklaracja etykiety jako symbolu SDX. Symbol może mieć maksymalnie długość 8-iu znaków. Dzięki temu po użyciu BLK UPDATE SYMBOLS asembler wygeneruje poprawny blok aktualizacji symboli. Np:

       pf  smb 'PRINTF'
           jsr pf
           ...

       cm  smb 'COMTAB'
       wp  equ cm-1       (błąd !)

           sta wp

       cm  smb 'COMTAB'

           sta cm-1       (ok !)

Uwaga: wszystkie deklaracje symboli należy użyć przed deklaracjami etykiet, jak i programem właściwym !

:repeat

Examples: 
           :4 asl @
           :2 dta a(*)

.REPT value

Przed dyrektywą .REPT może wystąpić etykieta, natomiast przed dyrektywą .ENDR już nie może występować etykieta.

.PRINT

.ERROR, ERT

 c+  włącz obsługę CPU 65816 (16bit)
 c-  włącz obsługę CPU 6502 (8bit)                           (default)
 h+  zapisuj nagłówek pliku dla DOS                          (default)
 h-  nie zapisuj nagłówka pliku dla DOS
 l+  zapisuj listing do pliku (LST)
 l-  nie zapisuj listingu (LST)                              (default)
 o+  zapisuj wynik asemblacji do pliku wynikowego (OBX)      (default)
 o-  nie zapisuj wyniku asemblacji do pliku wynikowego (OBX)
 s+  drukuj listing na ekranie
 s-  nie drukuj listingu na ekranie                          (default)

Wszystkie przełączniki OPT możemy używać w dowolnym miejscu listingu, czyli np. możemy włączyć zapis listingu w linii 12, a w linii 20 wyłączyć itd., wówczas plik z listingiem będzie zawierał tylko linie 12..20.

Jeśli używamy CodeGenie możemy użyć 'OPT S+', dzięki temu nie musimy przechodzić do pliku z listingiem, bo listing wydrukowany został w dolnym okienku (Output Bar) :)

 adr                 asembluj od adresu ADR, ustaw adres w nagłówku na ADR
 adr,adr2            asembluj od adresu ADR, ustaw adres w nagłówku na ADR2
 [b($ff,$fe)]        zmień nagłówek na $FFFE (zostaną wygenerowane 2 bajty)
 [$ff,$fe],adr       zmień nagłówek na $FFFE, ustaw adres w nagłówku na ADR
                     (6 bajtów)
 [$d0,$fe],adr,adr2  zmień nagłówek na $D0FE, asembluj od adresu ADR, ustaw
                     adres w nagłówku na ADR2 (6 bajtów)
 [a($FFFA)],adr      nagłówek SpartaDOS $FAFF, ustaw adres w nagłówku na ADR
                     (6 bajtów)

 [a($ffff),d'atari',c'ble',20,30,40],adr,adr2                    

Nawiasy kwadratowe [ ] służą określeniu nowego nagłówka, który może być dowolnej długości. Pozostałe wartości rozdzielone znakiem przecinka ',' oznaczają odpowiednio: adres asemblacji, adres w nagłówku pliku.

     b  wartość typu BYTE
     a  wartość typu WORD
     v  wartość typu WORD, relokowalna
     l  młodszy bajt wartości (BYTE)
     h  starszy bajt wartości (BYTE)
     t  wartość typu LONG (24bit)
     e  wartość typu LONG (24bit)
     f  wartość typu DWORD (32bit)
     g  wartość typu DWORD (32bit) w odwróconej kolejności     
     c  ciąg znaków ATASCII ograniczony apostrofami '' lub "", znak * na końcu spowoduje
        invers wartości ciągu, np. dta c'abecadlo'*
     d  ciąg znaków INTERNAL ograniczony apostrofami '' lub "", znak * na końcu spowoduje
        invers wartości ciągu, np. dta d'abecadlo'*

NMB (Next Memory Bank)

RMB (Reset Memory Bank)

     value        wartość z zakresu <0..$FFFB>
     =label       odczytuje numer banku przypisany do etykiety LABEL

.proc test {.word tmp .byte value}

 .byte "atari",5,22
 .word 12,$FFFF
 .long $34518F
 .dword $11223344

.AND, .OR, .XOR

.DS

.AND, .OR

where: 

centre     is a number which is added to every sine value 
amp        is the sine amplitude 
size       is the sine period 
first,last define range of values in the table. They are optional.
           Default are 0,size-1. 

Example: dta a(sin(0,1000,256,0,63))
         defines table of 64 words representing a quarter of sine with
         amplitude of 1000.

RND(min,max,length)

 .IF [IFT] expression
 .ELSE [ELS]
 .ELSEIF [ELI] expression
 .ENDIF [EIF]

W/w dyrektywy i pseudo rozkazy wpływają na przebieg asemblacji.

Procedur dotyczą n/w dyrektywy:

 name .PROC [{.Typ1 Par1 .Typ2 Par2 ...}]
 .PROC name [{.Typ1 Par1 .Typ2 Par2 ...}]
 .EXIT [expression]
 .ENDP

 @STACK_ADDRESS
 @STACK_POINTER

Brak deklaracji dla w/w etykiet i próba użycia struktury .PROC z zadeklarowanymi parametrami spowoduje wystąpienie błędu 'Undeclared label .STACK_ADDRESS' lub 'Undeclared label .STACK_POINTER'.

Jeśli chcemy przekazać parametry do procedury, musimy je zadeklarować. Deklaracja parametrów procedury mieści się pomiędzy nawiasami klamrowymi { }. Dostępne są trzy typy parametrów:

Bezpośrednio po deklaracji typu, oddzielona minimum jedną spacją, następuje nazwa parametru.

name .PROC {.WORD name_par1 .BYTE name_par2}

Aby tego dokonać MADS po napotkaniu w strukturze .PROC rozkazu .EXIT (albo .ENDP jeśli .EXIT nie wystąpiło) wymusza wykonanie makra @ExitProc, które użytkownik sam może zaprojektować, albo skorzystać z dołączonego do MADS'a (plik EXITPROC.ASM), które ma następującą postać:

@ExitProc .macro ' '

 .if :1<>0
  lda @stack_pointer
  tax
 
  sec
  sbc #:1
  sta @stack_pointer
 
   .if :0>1
     lda :2 
   .endif

 .endif 

 rts

 .endm

Poprzez rozkaz .EXIT można dodatkowo przekazać wartość lub wyrażenie (przez akumulator). Czyli taka procedura staje się już funkcją.

Jeśli jednak procedura nie miała zadeklarowanych parametrów, makro @ExitProc nie zostanie wymuszone i nie zostanie wygenerowany żaden rozkaz. Dodanie rozkazu RTS w ciele procedury przy wyjściu z każdej ścieżki jest obowiązkiem programującego, a nie assembler'a.

Makr dotyczą n/w pseudo rozkazy i dyrektywy:

name .MACRO ['separator'] ["separator"]
 .MACRO name ['separator'] ["separator"]
 .EXIT
 .ENDM
 :[%%]parameter

Za słowem .MACRO może wystąpić deklaracja separatora (pomiędzy apostrofem pojedyńczym lub podwójnym) i trybu przekazywania parametrów do makra (pojedyńczy apostrof bez zmian, podwójny apostrof z rozbijaniem parametrów).

'separator'

"separator"

 test #12 200 <30

test .macro " "
.endm


 test2 #12  ,  200  , <30

test2 .macro ""
.endm

Makro TEST ma zadeklarowany separator-spację oraz podwójny apostrof ", czyli po wywołaniu makra parametry zostaną rozłożone na:

 test '#' 12 ' ' 200 '#' 0

Tylko dla znaków '<' i '>' zostanie wyliczona wartość parametru. Przykład wykorzystania tak zadeklarowanych makr w pliku z makro rozkazami XASM'a ..\EXAMPLES\MACROS\XASM.ASM

.EXIT

.ENDM

 :$2 nop
 :+2 nop
 :%10 nop

  .IF :0<2 || :0>5
    .ERROR "Wrong number of arguments"
  .ENDIF

  IFT %%0<2 || :0>5
    ERT "Wrong number of arguments"
  EIF 

Przykład makra:

load_word .macro
   lda <:1
   sta :2
   lda >:1
   sta :2+1   
 .endm

 test ne
 test eq
 
.macro test
  b%%1 skip
.endm

Procedurę wywołujemy poprzez jej nazwę (identycznie jak makro), po niej mogą wystąpić parametry, rozdzielone separatorem w postaci znaku przecinka ',' (nie ma możliwości zadeklarowania innego separatora).

Jeśli przekazana liczba parametrów różni się od liczby zadeklarowanych parametrów w deklaracji procedury wystąpi komunikat błędu 'Improper number of actual parameters'.

Możliwe są trzy sposoby przekazania parametru:

Przykład wywołania procedury:

 proc_name @ , #$166 , $A400

MADS po napotkaniu wywołania procedury, która miała zadeklarowane parametry wymusza wykonanie makra @CALL. Jeśli jednak procedura nie miała zadeklarowanych parametrów, zamiast makra @CALL zostanie wynegerowany rozkaz JSR nazwa_procedury.

@CALL proc_name,'@','B',0,'#','W',358,' ',W,41984

Parametr przekazywany przez akumulator (@) powinien być zawsze na początku, jeśli wystąpi w innym miejscu zawartość akumulatora zostanie zmodyfikowana (domyślne makro @CALL nakłada takie ograniczenie). Oczywiście użytkownik może to zmienić pisząc swoją wersję makra @CALL

Jeśli chcemy dostać się do etykiet zadeklarowanych w procedurze spoza obszaru procedury, wówczas adresujemy (podobnie jak dla struktur .LOCAL) z użyciem znaku kropki '.', np.:

 lda test.pole1

test .proc
pole1 nop
 .endp

 rozkaz nazwa_struktury.pole_struktury

Jeśli poszukiwana przez assembler etykieta nie wystąpiła w obrębie procedury, wówczas nastąpi jej poszukiwanie w głównym programie.

.proc nazwa
 
 .exit #20
 
.endp

W makrze @ExitProc musi zostać zawarty program który zmodyfikuje wartość wskaźnika stosu @STACK_POINTER, jest to niezbędne w celu prawidłowego działania stosu programowego. Od wskaźnika stosu odejmowana jest liczba bajtów które zostały przekazane do procedury. Liczbę bajtów przekazaną do procedury przekazuje do makra @ExitProc MADS w postaci parametru.

Jeśli procedura nie miała zadeklarowanych parametrów i nie użyliśmy dyrektywy .EXIT w jej ciele tylko .ENDP, wówczas nie zostanie wywołane makro @ExitProc ani żaden inny rozkaz. Dodanie rozkazu RTS w ciele procedury przy wyjściu z każdej ścieżki jest obowiązkiem programującego, a nie assembler'a.

name .PROC {.WORD name_par1 .BYTE name_par2}

Etykiety parametrów w naszym w/w przykładzie przyjmą wartości:

liczba_bajtów_parametru = 0

name_par1 = @STACK_ADDRESS - liczba_bajtów_parametru

liczba_bajtów_parametru = liczba_bajtów_parametru + 2  (WORD)

name_par2 = @STACK_ADDRESS - liczba_bajtów_parametru

liczba_bajtów_parametru = liczba_bajtów_parametru + 1  (BYTE)

 ldx @stack_pointer
 
 lda name_par1,x
 clc
 adc <$4000
 sta WYNIK
 
 lda name_par1+1,x
 adc >$4000
 sta WYNIK+1

Odczytanie wartości parametrów możliwe jest tylko przy adresowaniu indeksowym. Użytkownik nie powinien ingerować w wartość @STACK_POINTER tylko zostawić to zadanie dedykowanym makrom.

@GetPar .macro

 ldx @stack_pointer
 lda :1,x

 .endm

 @GetPar name_par1
 clc
 adc <$4000
 sta WYNIK

 @GetPar name_par1+1
 adc >$4000
 sta WYNIK+1

Makro wywołujemy poprzez jego nazwę, po niej mogą wystąpić parametry makra, rozdzielone separatorem którym jest domyślnie znak przecinka ','. Liczba parametrów uzależniona jest od wolnej pamięci komputera PC. Jeśli przekazana liczba parametrów jest mniejsza od liczby parametrów używanych, wówczas pod brakujące parametry zostanie podstawiona wartość $FFFFFFFF.

 macro_name [Par1, Par2, Par3, 'Par4', "string1", "string2" ...]

Apostrofy pojedyńcze ' ' zostaną przekazane razem ze znakami znajdującymi sie pomiędzy nimi.

Apostrofy podwójne " " oznaczają ciąg znaków i tylko ciąg znaków znajdujący się pomiędzy apostrofami zostanie przekazany.

Wszelkie deklaracje etykiet w obrębie makra są typu lokalnego. Aby odwołać się do etykiety globalnej o takiej samej nazwie jak lokalna należy poprzedzić ją znakiem dwukropka ':'.

Przykład wywołania makra:

 macro_name 'a',a,>$a000,cmp    ; dla domyślnego separatora ','
 macro_name 'a'_a_>$a000_cmp    ; dla zadeklarowanego separatora '_'
 macro_name 'a' a >$a000 cmp    ; dla zadeklarowanego separatora ' '

Przykład makra, które spowoduje przepełnienie stosu:

skok .macro

      skok

     .endm

 org $2000
 
 proc PutChar,'a'-64    ; wywołanie makra PROC, jako parametr
 proc PutChar,'a'-64    ; nazwa procedury która będzie wywołana przez JSR
 proc PutChar,'r'-64    ; oraz jeden argument (kod znaku INTERNAL)
 proc PutChar,'e'-64
 proc PutChar,'a'-64

 proc Kolor,$23         ; wywołanie innej procedurki zmieniającej kolor tła

;---

loop jmp loop           ; pętla bez końca, aby zobaczyć efekt działania

;---

proc .macro             ; deklaracja makra PROC
 push =:1,:2,:3,:4      ; wywołanie makra PUSH odkładającego na stos argumenty
                        ; =:1 wylicza bank pamieci
 
 jsr :1                 ; skok do procedury (nazwa procedury w pierwszym parametrze)
 
 lmb #0                 ; Load Memory Bank, ustawia bank na wartosc 0
 .endm                  ; koniec makra PROC 

;---

push .macro             ; deklaracja makra PUSH

  lmb #:1               ; ustawia bank pamieci

 .if :2<=$FFFF          ; jesli przekazany argument jest mniejszy równy $FFFF to
  lda <:2               ; odłóż go na stosie
  sta stack
  lda >:2
  sta stack+1
 .endif 

 .if :3<=$FFFF
  lda <:3
  sta stack+2
  lda >:3
  sta stack+3
 .endif 

 .if :4<=$FFFF
  lda <:4
  sta stack+4
  lda >:4
  sta stack+5
 .endif 
 
 .endm
 

* ------------ *            ; procedura KOLOR
*  PROC Kolor  *
* ------------ *
 lmb #1                     ; ustawienie numeru banku na 1
                            ; wszystkie deklaracje będą teraz należeć do tego banku
stack org *+256             ; stos dla procedury KOLOR
color equ stack

Kolor                       ; kod procedury KOLOR
 lda color
 sta 712
 rts

 
* -------------- *          ; procedura PUTCHAR
*  PROC PutChar  *
* -------------- *
 lmb #2                     ; ustawienie numeru banku na 2
                            ; wszystkie deklaracje będą teraz należeć do tego banku
stack org *+256             ; stos dla procedury PUTCHAR
char  equ stack

PutChar                     ; kod procedury PUTCHAR
 lda char
 sta $bc40
scr equ *-2

 inc scr
 rts

Prościej i efektywniej jednak skorzystać z deklaracji struktury .PROC jaką umożliwia MADS. Więcej o deklaracji procedury i operacjach jej dotyczących w rozdziale "Procedury".

W MADS przez pojęcie "bank pamięci" rozumiany jest każdy obszar zdefiniowany przez numer banku. Czyli bank pamięci to nie zawsze obszar $4000..$7FFF, ale każdy obszar o zdefiniowanym numerze z zakresu <$0000..$FFFB>.

Etykiety zadeklarowane w obszarze dla którego BANK > 0 są lokalne.

 NMB
 RMB
 LMB #value

Zwiększa o 1 aktualny numer banku (BANK = BANK + 1).

Ustawia numer banku na zero (BANK = 0).

     value        wartość z zakresu 0..$FFFE
     =label       odczytuje numer banku używany przez zmienną o etykiecie LABEL

Ustawia numer banku na nową wartość (BANK = value).

 org $2000
 lda #$e3
 sta $d301
 rts
 ini $2000

 nmb            ; bank = bank + 1   (next memory bank)
 
 org $4000

 icl 'program_w_dodatkowym_banku_pamieci.asm'

 org $2000
 lda #$e3
 sta $d301
 rts
 ini $2000

 lmb #$e3       ; bank = $E3        (load memory bank)
 
 org $4000

 icl 'program_w_dodatkowym_banku_pamieci.asm'

Czyli musimy zatroszczyć się o to aby do PORTB wpisać konkretny kod banku rozszerzonej pamięci, zanim blok danych zostanie wczytany w obszar $4000..$7FFF lub inny. MADS zapisuje plik wynikowy w formacie Atari DOS, który nie przewiduje specjalnych nagłówków dla bloków ładujących się do pamięci rozszerzonej.

Binary operators:

+   Addition
-   Subtraction
*   Multiplication
/   Division
%   Remainder
&   Bitwise and
|   Bitwise or
^   Bitwise xor
<<  Arithmetic shift left
>>  Arithmetic shift right
=   Equal
==  Equal (same as =)
<>  Not equal
!=  Not equal (same as <>)
<   Less than
>   Greater than
<=  Less or equal
>=  Greater or equal
&&  Logical and
||  Logical or


Unary operators:

+  Plus (does nothing)
-  Minus (changes sign)
~  Bitwise not (complements all bits)
!  Logical not (changes true to false and vice versa)
<  Low (extracts low byte)
>  High (extracts high byte)
^  High 24bit (extracts high byte)
=  Extracts memory bank
:  Extracts global variable value

Operator precedence:

first []              (brackets)
 + - ~ < >            (unary)
 * / % & << >>        (binary)
 + - | ^              (binary)
 = == <> != < > <= >= (binary)
 !                    (unary)
 &&                   (binary)
last  ||              (binary)

Dostępne rozkazy 6502

   LDA   LDX   LDY   STA   STX   STY   ADC   AND  
   ASL   SBC   JSR   JMP   LSR   ORA   CMP   CPY  
   CPX   DEC   INC   EOR   ROL   ROR   BRK   CLC  
   CLI   CLV   CLD   PHP   PLP   PHA   PLA   RTI  
   RTS   SEC   SEI   SED   INY   INX   DEY   DEX  
   TXA   TYA   TXS   TAY   TAX   TSX   NOP   BPL  
   BMI   BNE   BCC   BCS   BEQ   BVC   BVS   BIT  

   .b lub .z          BYTE
   .a lub .w lub .q   WORD

np.
   lda.w $80   ; zapisze AD 80 00
   lda   $80   ; zapisze A5 80     

Dostępne rozkazy 65816

   STZ   SEP   REP   TRB   TSB   BRA   COP   MVN  
   MVP   PEA   PHB   PHD   PHK   PHX   PHY   PLB  
   PLD   PLX   PLY   RTL   STP   TCD   TCS   TDC  
   TSC   TXY   TYX   WAI   WDM   XBA   XCE   INA
   DEA

   .b lub .z          BYTE
   .a lub .w lub .q   WORD
   .t lub .l          TRIPLE, LONG (24bit)

np.
   lda.w #$00     ; zapisze A9 00 00
   lda   #$80     ; zapisze A9 80

Wyjątki stanowią rozkazy n/w, którym nie można zmienić rozmiaru rejestru w adresowaniu absolutnym (niektóre assemblery nie wymagają dla tych rozkazów podania znaku '#', jednak MADS wymaga tego)

   SEP   REP   COP

   PEA

Innym wyjątkiem jest tryb adresowania pośredni długi, który reprezentowany jest przez nawiasy kwadratowe [ ]. Jak wiemy tego typu nawiasy wykorzystywane są też do obliczania wyrażeń, jednak jeśli asembler napotka pierwszy znak '[' uzna to za tryb adresowania pośredni długi i jeśli nie zasygnalizowaliśmy chęci używania 65816 wystąpi błąd 'Illegal adressing mode'. Aby "oszukać" assembler wystarczy dać przed kwadratowym nawiasem otwierającym '[' znak '+'.

 lda [2+4]     ; lda [6]
 lda +[2+4]    ; lda 6

Etykiety mogą być typu lokalnego lub globalnego, w zależności od miejsca w jakim zostały zadeklarowane.

 EQU
  =

Przykład deklaracji etykiety:

?nazwa   EQU  $A000
nazwa     =   20
nazwa2=12
@?nazwa  EQU  'a'+32

Czyli doszła możliwość użycia znaku zapytania '?' i "małpki" '@' w nazwach etykiet. Znak kropki '.' na początku nazwy sugeruje że jest to dyrektywa assemblera, natomiast znak zapytania '?' oznacza etykietę lokalną.

Zapis z użyciem przecinka ',' odwołania do struktury, czy rozszerzenia mnemonika jest niezbyt udany:

  lda nazwa_stuktury,pole,x
  
  lda,w #$00

  lda nazwa_stuktury.pole,x
  
  lda.w #$00

Maksymalna liczba etykiet i makr ograniczona jest ilością pamięci komputera PC. Konkretnie można dokonać 2147483647 (INTEGER) wpisów do tablic dynamicznych. Jestem pewien że taka ilość jest wystarczająca :)

Jeden wiersz może mieć długość 65536 bajtów, takiej długości może być też nazwa etykiety. Nie miałem jednak okazji sprawdzić tak długich etykiet i wierszy :)

Obszarów lokalnych dotyczą n/w dyrektywy:

 name .LOCAL
 .LOCAL name
 .ENDL

Jeśli poszukiwana przez assembler etykieta nie wystąpiła w obrębie obszaru .LOCAL, wówczas nastąpi jej szukanie w obszarze makra (jeśli jest aktualnie przetwarzane), potem w procedurze (jeśli procedura jest aktualnie przetwarzana), na końcu w głównym programie.

 lda obszar_lokalny.etykieta_w_obszarze_lokalnym
 
 lda name_local.local_label

Czyli używamy znaku kropki '.' w adresowaniu takiej struktury .LOCAL (odwołania do .PROC spoza procedury podobnie).

Deklaracja obszaru lokalnego o nazwie name. Nazwa obszaru jest wymagana i konieczna, jej brak wygeneruje błąd. Do nazw obszaru nie można używać nazw mnemoników i pseudo rozkazów.

Zakończenie deklaracji obszaru lokalnego.

 org $2000
 
tmp ldx #0   <-------------   etykieta w obszarze globalnym
                          |
 lda obszar.pole  <---    |   odwolanie do obszaru lokalnego
                     |    |
obszar .local        |    |   deklaracja obszaru lokalnego
                     |    |
 lda tmp   <---      |    |
              |      |    |
 lda :tmp     |      | <---   odwolanie do obszaru globalnego
              |      |
tmp nop    <---      |        deklaracja w obszarze lokalnym
                     | 
pole lda #0       <---   <--- deklaracja w obszarze lokalnym
                            |
 lda pole  <----------------- odwolanie w obszarze lokalnym

 .endl                        koniec deklaracji obszaru lokalnego

Etykieta (deklaracja) lokalna posiada tą właściwość, że jej wartość może ulegać zmianie. Normalnie próba ponownej deklaracji etykiety kończy się komunikatem 'Label declared twice'. Nie będzie takiego komunikatu jeśli jest to etykieta lokalna.

 ?name

?loc = $567
?loc2 = $4444

	 lda ?loc
	 sta ?loc2

?loc = $123

	 lda ?loc

lp   ldx #0         ; deklaracja globalna etykiety 'LP' 

     test
     test
 
test .macro

      lda :lp       ; znak ':' przed etykietą odczyta wartość etykiety globalnej

      sta lp+1      ; odwołanie do etykiety lokalnej 'LP' w makrze
lp    lda #0        ; deklaracja etykiety lokalnej 'LP'

     .endm

Label table:
00	2000	LP     - wartość etykiety globalnej LP
00	2008	LP:1   - wartość etykiety lokalnej LP po pierwszym wywołaniu makra
00	2010	LP:2   - wartość etykiety lokalnej LP po drugim wywołaniu makra
00	2012	LP::1  - wartość etykiety lokalnej LP w pierwszym makrze przed jego wywołaniem

Do oznaczania komentarza jednoliniowego najbezpieczniej jest używać średnika ';' ponieważ znak '*' ma też inne znaczenia, może oznaczać operacje mnożenia, czy też aktualny adres podczas asemblacji. Średnik natomiast dedykowany jest tylko i wyłącznie do oznaczenia komentarza.

; to jest komentarz
                 ; to jest komentarz
 lda #0      ; to jest komentarz
 dta  1 , 3     * BŁĘDNY KOMENTARZ, ZOSTANIE ŹLE ZINTERPRETOWANY
 
 org $2000 + 1      BŁĘDNY KOMENTARZ, ZOSTANIE ŹLE ZINTERPRETOWANY

 nop // to jest komentarz

 // to jest komentarz
 
/*
  ...
  to jest komentarz wieloliniowy
  ...
*/

/*************************************
  to tez jest komentarz wieloliniowy
**************************************/

Znaki oznaczające komentarz wieloliniowy '/* */' można stosować tylko na początku linii, mogą być poprzedzone spacjami lub tabulatorami.

Znaki oznaczające komentarz jednoliniowy '//' można stosować tak samo jak średnik ';', czyli bez ograniczeń.

Definicje są zawsze typu globalnego, tzn. że niezależnie od tego czy definicja wystąpi w obszarze makra, procedury czy programu głównego to zawsze będzie widoczna.

 EQU
  =

Przykład definicji:

   ?nazwa   = $A000
   nazwa  EQU 20
   @?nazwa  = 'a'+32

@CALL .macro
 ?@stack_offset = 0
 
 ...
 ...
 
 
@CALL_@ .macro

  sta @stack_address+?@stack_offset,x
  ?@stack_offset = ?@stack_offset+1

 .endm 

Przykład zaczerpnięty ze strony

Składnia dotycząca obsługi Sparta DOS X, zaczerpnięta została z FastAssemblera autorstwa Marka Goderskiego, poniżej cytat z instrukcji dołączonej do FA. Pliki źródłowe *.FAS można obecnie bez większych problemów asemblować MADS'em. Rozkazy relokowalne mają zawsze 2 bajtowy argument, nie ma obecnie możliwości relokowania 3 bajtowych argumentów (65816).

Najważniejszą nowością w SDX dla programisty jest możliwość prostego pisania programów relokowalnych. Ponieważ procesor MOS 6502 nie posiada adresowania względnego, (prócz krótkich skoków warunkowych) programiści z ICD zastosowali specjalne mechanizmy ładowania bloków programu. Cały proces polega na załadowaniu bloku, a następnie specjalnego bloku aktualizacji adresów. Wszystkie adresy w bloku programu są liczone od zera. Wystarczy więc dodać do nich wartość memlo aby otrzymać adres właściwy. Które adresy zwiększyć, a które pozostawić? Właśnie po to jest specjalny blok aktualizacji który zawiera wskaźniki (specjalnie kodowane) do tychże adresów. Tak więc po bloku lub blokach RELOC obowiązkowe jest wykonanie UPDATE ADRESS dla poprawnego działania programu. Również po blokach SPARTA w których rozkazy (lub wektory) odwołują się do bloków RELOC lub EMPTY obowiązkowe jest wykonanie UPDATE ADRESS.

Następną innowacją jest wprowadzenie symboli. Otóż niektóre procedury usługowe SDX zostały zdefiniowane za pomocą nazw! Nazwy te maja zawsze 8 liter (podobnie jak nazwy plików). Zamiast korzystać z tablic wektorów lub skoków (jak w OS) korzystamy z symboli definiowanych SMB. Po wczytaniu bloku lub bloków programu SDX ładuje blok aktualizacji symboli i w podobny sposób jak przy blokach relokowalnych zamienia adresy w programie. Symbole mogą być używane dla bloków RELOC i SPARTA.

Programista może zdefiniować własne symbole zastępujące SDX lub zupełnie nowe dla wykorzystania przez inne programy. Robi się to poprzez blok UPDATE NEW. Trzeba jednak wiedzieć że nowy symbol musi być zawarty w bloku RELOC.

Liczba bloków RELOC i EMPTY jest ograniczona do 7 przez SDX.

Bloki takie można łączyć w łańcuchy np:

       blk sparta $600
       ...

       blk reloc main
       ...

       blk empty $100 main
       ...

       blk reloc extended
       ...

       blk empty $200 extended

Łańcuch taki nie jest przerywany przez aktualizację adresów, lub symboli ale jest niszczony przez definicję nowego symbolu, oraz inne bloki (np: dos).

Uwaga: Łańcuch taki ma sens tylko wtedy gdy wszystkie jego bloki ładują się do tej samej pamięci, lub gdy program przy odpowiednich odwołaniach przełącza pamięć.

Uwaga: Rozkazy i wektory w blokach RELOC i EMPTY nie powinny odwoływać się do bloków SPARTA! Może to spowodować błąd gdy użytkownik załaduje program komendą LOAD, a użyje go po dłuższym czasie. O ile bloki RELOC i EMPTY były bezpieczne to nigdy nie wiadomo co jest w pamięci tam gdzie ostatnio był blok SPARTA!

Równie niebezpieczne jest używanie odwołań do bloków RELOC i EMPTY przez bloki SPARTA (powód jak wyżej), jednakże podczas instalowania nakładek (*.sys) z użyciem INSTALL jest to czasem niezbędne, stąd jest dopuszczalne. Można także inicjować blok SPARTA (porzez $2E2) będzie on wtedy zawsze uruchomiony, a potem już zbędny.

Uwaga: Pomiędzy blokami SPARTA, a RELOC i EMPTY może dojść do kolizji adresów! FA rozpoznaje odwołania do innych bloków poprzez adresy, przyjmując PC dla RELOC i EMPTY od $1000, tak więc gdy mieszamy te bloki należy mieć pewność ze SPARTA leży poniżej $1000 (np:$600) lub powyżej ostatniego bloku relokowalnego, zazwyczaj wystarcza $4000. Błąd taki nie jest przez kompilator wykrywany !

Przedruk z Serious Magazine, autor Qcyk/Dial.

Plik sam w sobie jest tylko niewiele wartym zbiorem bajtów. Mnóstwo liczb, które mogą oznaczać wszystko, a zarazem nic, jeśli nie wiadomo jak je zinterpretować. Większość plików wyposaża się z tego powodu w różnorodne nagłówki, w których pamiętane są informacje o tym co plik zawiera, ew. jak go potem traktować przy odczycie. Do takich należą również pliki wykonywalne, binarne, czy po prostu: przeznaczone do załadowania z poziomu DOS'u. Wszak DOS to też program i jak każdy inny ma prawo oczekiwać danych o określonej, znanej mu strukturze.

Tradycyjne pliki binarne, rozpoznawane przez wszystkie DOS'y dla komputerów Atari XL/XE, mają budowę blokową, gdzie każdy blok posiada swój nagłówek. Istnieją dwa rodzaje nagłówków:

 1. dta a($ffff),a(str_adr),a(end_adr)

 2. dta a(str_adr),a(end_adr)

str_adr - adres, pod który zostanie załadowany pierwszy bajt danych

end_adr - adres, pod który zostanie załadowany ostatni bajt

Pierwszy blok w pliku musi mieć nagłówek typu $ffff, pozostałe bloki dowolnie. Za nagłówkiem oczywiście powinny znaleźć się dane w ilości:

   (end_adr-str_adr)+1

Tyle tytułem przypomnienia. Twórcy systemu Sparta DOS X zachowali powyższy standard, dodając jednocześnie kilka nowych typów nagłówków. Ciągle więc mamy do czynienia z plikiem podzielonym na bloki, z tym że rodzajów bloków jest teraz dużo więcej. Oto one:

1. Blok nierelokowalny (ładowany pod stały adres w pamięci):

    dta a($fffa),a(str_adr),a(end_adr)

Jest to to samo co blok $ffff - nie ma znaczenia, który zostanie użyty. $fffa będzie jednak wyraźnie wskazywać, że program jest przeznaczony dla SDX - inny DOS takiego pliku nie odczyta.

2. Blok relokowalny (ładowany pod MEMLO we wskazany rodzaj pamięci):

    dta a($fffe),b(blk_num),b(blk_id)
    dta a(blk_off),a(blk_len)

blk_num - numer bloku w pliku. Każdy blok relokowalny powinien posiadać swój własny numer. Ponieważ adresy ładowania bloków nie są znane, bloki identyfikowane są właśnie poprzez swoje numery. Mogą one przyjmować wartości z zakresu 0-7, z tym że w praktyce stosuje się zwykle numerację od 1 w górę.

blk_id - bity 1-5 stanowią indeks pamięci, do której blok ma zostać załadowany. Spotkałem się z dwoma wartościami:

 $00 - pamięć podstawowa
 $02 - pamięć rozszerzona

blk_off - tzw. przesunięcie adresów w bloku, czyli po prostu adres, pod który był assemblowany kod. Jest to potrzebne przy uaktualnianiu adresów odwołujących się do zawartości bloku.

blk_len - długość bloku. Tyle danych powinno być za nagłówkiem chyba, że jest to blok rezerwujący pamięć wtedy danych nie ma.

       lda coś
       ...
      coś equ *
       ...
    Zamiast tego, pozostaje np.:
       lda _coś
       ldx _coś+1
       ...
      _coś dta a(coś)
       ...
      coś equ *

3. Blok aktualizacji adresów odnoszących się do bloku relokowalnego:

    dta a($fffd),b(blk_num),a(blk_len)

blk_num - numer bloku, do którego odnoszą się uaktualniane adresy.

blk_len - długość bloku aktualizacji (bez nagłówka). Jest ona ignorowana.

Adresy są uaktualniane poprzez dodanie do adresu istniejącego różnicy pomiędzy adresem, pod który został załadowany wskazany blok relokowalny, a wartością blk_off (adresem asemblacji) tego bloku. Można to przedstawić wzorem:

       ADR=ADR+(blk_adr-blk_off)

"Ciało" bloku aktualizacji stanowią wskaźniki do poprawianych adresów oraz rozkazy specjalne. Wskaźnik jest liczbą z zakresu $00-$fb i oznacza przesunięcie względem miejsca poprzedniej aktualizacji. Miejsce to jest pamiętane przez program ładujący jako bezpośredni adres, nazwijmy go licznikiem aktualizacji. Licznik ten można zainicjować za pomocą funkcji specjalnych, którymi są liczby większe od $fb:

$fc oznacza koniec bloku aktualizacji,

$fd,a(ADDR) następuje aktualizacja adresu wskazanego bezpośrednio przez ADDR. Tym samym wartość ADDR jest wpisywana do licznika aktualizacji i od niej będą liczone kolejne przesunięcia,

$fe,b(blk_num) do licznika aktualizacji wstawiany jest adres bloku wskazanego przez blk_num, czyli kolejne aktualizacje będą się odnosiły do kodu zawartego w tym bloku,

$ff licznik aktualizacji zwiększany jest o $fa (bez aktualizacji adresu).

4. Blok aktualizacji adresów procedur zdefiniowanych symbolami:

    dta a($fffb),c'SMB_NAME',a(blk_len)

SMB_NAME - symboliczna nazwa procedury (lub tablicy, rejestru systemowego itp.) Osiem znaków w kodzie ATASCII,

blk_len - jak w bloku $fffd.

Po nagłówku występuje ciąg wskaźników określających położenie adresów do zaktualizowania - identycznie jak w bloku $fffd. Adresy są zmieniane poprzez dodanie do istniejącego adresu, adresu procedury określonej symbolem. Pozwala to na wykorzystywanie w programach procedur, których adresów nie znamy, np. procedur dodawanych przez inne programy uruchamiane w środowisku SDX. Także procedury systemowe powinny być wykorzystywane w ten sposób, przecież mogą one mieć różne adresy w różnych wersjach Sparty.

5. Blok definicji nowych symboli:

    dta a($fffc),b(blk_num),a(smb_off)
    dta c'SMB_NAME'

blk_num - numer bloku, w którym znajduje się definiowana procedura. Wynika z tego, że procedura musi być załadowana jako blok relokowalny.

smb_off - przesunięcie adresu procedury w bloku, czyli offset procedury względem początku bloku (pierwszy bajt ma numer 0) powiększony o wartość blk_off tego bloku. Inaczej jest to adres pod jaki procedura została zassemblowana, SMB_NAME - symboliczna nazwa definiowanej procedury.

Bloki typu $fffb, $fffc, $fffd nie są na stałe zatrzymywane w pamięci. System wykorzystuje je tylko podczas ładowania programu.