; Installer for GEMImageDT. V1.1.
; Copyright © 2002 Neil Cafferkey.
; $VER: "Install GEMImageDT" 1.1 (27.3.2002)


; Set constants

(set #kick-too-low-msg "Kickstart 3.0 or greater is required.")
(set #exit-msg "Installation complete!")

(set #class-name "gemimage.datatype")
(set #classes-source "Classes/DataTypes")
(set #classes-dest "LIBS:DataTypes")
(set #descriptor-name "GEMImage")
(set #descriptors-source "Devs/DataTypes")
(set #descriptors-dest "DEVS:DataTypes")


; Check Kickstart version

(if (< (/ (getversion) 65536) 39)
   (abort #kick-too-low-msg)
)


; Install class

(copylib
   (source (tackon #classes-source #class-name))
   (dest #classes-dest)
   (help @copylib-help)
)


; Install descriptor

(copyfiles
   (source (tackon #descriptors-source #descriptor-name))
   (dest #descriptors-dest)
   (infos)
   (help @copyfiles-help)
)


; Notify system about new DataType

(run ("AddDataTypes \"%s\"" (tackon #descriptors-dest #descriptor-name)))


; Exit

(exit #exit-msg (quiet))


; Make sure the standard welcome screen never appears

(welcome)