; SAVE#D3:WMONOEND.M65
;   .OPT NO LIST
;
      .OPT NO EJECT
;
;     WMONOEND.M65
;    MONOPOLY WILLIAMS
STADD =   $A100
CTEND =   $C000
CTADD = $BF00
CTDST = $0400
BUILD = $6000
OFFSET = CTADD-CTDST-BUILD
;
    .SET 6,$5B00
    *=  $0400
;
TIPTAB
    .BYTE $1F,$A0,$10,$00
    .BYTE $1E,$10,$81,$08
    .BYTE $01,$2E,$A1,$08
    .BYTE $03,$A0,$2C,$01
    .BYTE $01,$A3,$30,$01
    .BYTE $01,$A4,$32,$01
    .BYTE $02,$A5,$38,$01
    .BYTE $03,$A7,$3C,$01
    .BYTE $0E,$AA,$40,$01
    .BYTE $06,$B8,$50,$01
    .BYTE $01,$BF,$59,$01
    .BYTE $09,$A0,$5A,$02
    .BYTE $0F,$A8,$70,$04
    .BYTE $0F,$70,$A0,$08
    .BYTE $03,$A9,$60,$02
    .BYTE $1D,$AC,$64,$02
    .BYTE $20,$A0,$78,$03
    .BYTE $08,$A0,$98,$04
    .BYTE $08,$B7,$30,$04
;
DO_OVER
    LDA TIPTAB,X
    STA $E4
    INX 
    LDA TIPTAB,X
    STA $E1
    INX 
    LDA TIPTAB,X
    STA $E3
    INX 
    LDA TIPTAB,X
    TAY 
    STA $D500,Y
    INX 
    LDY #$00
    STY $E0
    STY $E2
?3  LDA ($E0),Y
    STA ($E2),Y
    INY 
    BNE ?3
    INC $E1
    INC $E3
    DEC $E4
    BNE ?3
    RTS 
;
GOPLAY
    INC $42
    STA $D400
    LDA # <MEAN
    STA $02
    LDA # >MEAN
    STA $03
    INC $09
    LDA #$07
    LDX #$30
    JSR ?2
    JMP $7008
;
START2
    LDX #$00
    LDA #$0C
?2  STA $E5
?4  JSR DO_OVER
    DEC $E5
    BNE ?4
    LDA #$C0
    STA $02E4
    STA $6A
    STY $D508
    STY $03FA
    STY $42
    RTS 
;
MEAN
    LDA #$00
    INC $42
    STA $D400
    STA $D500
    JMP $E477
;
    .SET 6,$A000
    *=  $BFFA-$3B
INIT STX $03E9  ;CKEY=0
    STX $03EA   ;CASSBT=0
    DEX 
    STX $D301   ;KILL BASIC HARD
    LDA #$01
    STA $09     ;SAY BOOTED
    STA $42
    STA $03F8   ;KILL BASIC SOFT
    LDA # <STADD ;LOAD
    STA $0A     ;DOSVEC WITH
    STA $0C     ;DOSINI AND
    STA $02     ;CASINI WITH
    LDA # >STADD ;LOAD
    STA $0B     ;DOSVEC+1
    STA $0D     ;DOSINI+1
    STA $03     ;CASINI+1
    LDY #$00
    LDA #$BF
    STA $E1
    LDA #$04
    STA $E3
    STY $E0
    STY $E2
?A  LDA ($E0),Y
    STA ($E2),Y
    INY 
    BNE ?A
    JMP START2
;
XTLEN = *-INIT
    *=  $BFFA
    .BYTE "FU"
    .BYTE $00   ;MUST BE 0
    .BYTE $00   ;DOS=5,NODOS=4
    .WORD INIT
;ORIGIN AT 150