poczatek       equ $4900

               org poczatek
               opt %0100101

* --- system --- *
dliv           equ 512
dmactls        equ 559
dlist          equ 560
nmien          equ 54286
wsync          equ 54282
vcount         equ 54283
chbase         equ 54281
* --- stale --- *
infofont       equ $b400
fonts          equ $b800
* --- strona0 --- *
zero           equ $f0

reals          equ zero *wyraz

pusty     equ 16
prkraj    equ 24
poclw3    equ 66
lwkraj    equ 20
zapora    equ 38
pradnica  equ 74
pozzap    equ 76
pozpradnica    equ 78

modul    equ $3400
fx_adr   equ $3bc2

m_init   equ modul+3
m_tact   equ modul+6


kieszen        equ 1152

pmadres        equ $800

zn             equ zero+2
sp             equ zero+4
tl             equ zero+6
def            equ zero+8
__zero         equ zero+$a
_memory        equ zero+$c

_table         equ $500 tablica do mnozenia
table          equ $600 tablica masek


*kieszen+
* 0 - dyskietki
* 1 - naboje
* 2 - paliwo
* 3 - niesmiertelnosc


h2             equ *

               jsr _pmbclear
               jsr $7fb0

               lda 53279
               cmp #6
               bne *-5

               lda #64
               sta 54286
               lda #0
               sta 559
               lda #$40
               jsr m_init


               lda #255
               sta zwolnij+4

               jsr _uzup

               lda #0
               sta kieszen
               sta kieszen+1
               sta kieszen+5
               sta kieszen+4
               lda #$14
               sta kieszen+2
               lda #0
               sta zwolnij+3

               ldx #0
               txa
               sta _service_nr,x
               inx
               cpx #13
               bne *-6
               lda #$71
               ldx #100
               sta _pos_Y
               stx _pos_X

               jsr play_the_game

               jmp h2

game_over      equ *

               lda #0
               ldx #2
               jsr m_init

               jsr _pmbclear
               lda <go_disp
               sta 560
               lda >go_disp
               sta 561
               lda #$b4
               sta 756

               lda #$d6
               sta 708
               lda #$5a
               sta 709
               lda #$4f
               sta 710

               lda 644
               bne *-3
               rts

winner         equ *

               lda #0
               ldx #1
               jsr m_init

               jsr _pmbclear
               lda <fi_disp
               sta 560
               lda >fi_disp
               sta 561
               lda #$b4
               sta 756

               lda #$d6
               sta 708
               lda #$7a
               sta 709
               lda #$6f
               sta 710

               lda 644
               bne *-3
               rts

play_the_game  equ *

               jsr _pmbclear
               jsr _makemask
               jsr _maketable

               lda kieszen+6
               beq *+13
               jsr 1160
               lda kieszen+6
               eor #255
               sta kieszen+6

               ldx <fx_adr
               ldy >fx_adr
               lda #$70
               jsr m_init
               lda #0
               tax
               jsr m_init


               lda <$8700+1
               sta reals
               lda >$8700+1
               sta reals+1

               lda #3
               sta 730

               lda #$76
               sta 704
               lda #$78
               sta 705
               lda #$5f
               sta 706
               lda #$a4
               sta 708
               lda #$6a
               sta 709
               lda #$1f
               sta 710
               lda #2
               sta 707
               lda #12
               sta 711

               lda 623
               ora #%00010001
               sta 623
               lda >pmadres
               sta 54279
               lda #3
               sta 53277

               lda 20
               cmp 20
               beq *-2
               lda #255
               sta _service_nr
               sta spnr
               jsr _newwsp
               jsr init
               jsr translacja
               lda #1
               sta tempo

               lda #2
               ldx #0
               sta zebratable,x
               inx
               cpx #46
               bne *-6
               lda #$40
               sta zegar+1
               lda #$00
               sta zegar+2

               ldx >nmir
               ldy <nmir
               lda #7
               jsr $e45c

_change        equ *

               lda #90
               cmp 54283
               bne *-3
               lda chnmi
               bne _change

               lda zwolnij+5
               beq *+5
               dec zwolnij+5

               lda 53279
               cmp #3
               bne *+16
               lda #255
               sta zwolnij+4
               lda #0
               tax
               jsr m_init
               jmp *+17
               cmp #5
               bne *+12
               lda #0
               sta zwolnij+4
               lda #$40
               jsr m_init

               lda kieszen+5
               cmp #4
               bne *+7
               lda #104
               sta eltable

               lda zwolnij+3
               beq *+6
               jsr winner
               rts

               lda zegar+1
               ora zegar+2
               bne *+5
               jmp game_over

               ldx #0
               lda linia,x
               cmp #1
               beq dd
               cmp #2
               beq dd
               cmp #3
               beq dd
               cmp #4
               beq dd
               inx
               cpx #128
               bne *-22
               jsr game_over
               rts

               nop
               nop
               nop
               nop

        dta d'     '

dd             equ *

               lda 764
               cmp #28
               bne *+5
               jmp game_over
               cmp #33
               bne *+26
               inc kieszen
               inc kieszen+1
               inc kieszen+2
               inc kieszen+3
               inc kieszen+4
               inc kieszen+5
               inc 764
               jsr _uzup

               jsr _zap_rozpoznaj
               ldx #0             *
               jsr _opn_door      *

               jsr _inf
               jsr _p_prog
               jmp _change

_p_prog        jsr _zm
               jsr _movemissile
               jsr _miskolision

               lda opoznienie
               beq *+5
               dec opoznienie
               inc licz

               lda licz2
               eor #255
               sta licz2
               bne *+5

               jsr _luup

               lda licz
               cmp #3
               beq *+3
               rts

               lda #0
               sta licz
               jsr _ruch
               rts

nmir           jsr dli_on
               jmp nmi


_luup          lda _fz05
               eor #255
               sta _fz05

               lda kieszen+3
               bne _luup3
               lda #2
               sta 707
               jmp _luup2
_luup3         inc 707
               dec kieszen+3

_luup2         lda _service_nr
               beq _lot
               jsr _joystick
               jsr _main
               jsr _pmXY
               jsr pociski
               rts
_lot           jsr _air_hero
               jsr _pmXY
               rts

licz           dta b(0)
licz2          dta b(0)


_ruch          equ *

               lda #0
               sta 77
               jsr _zapora

               ldy #0

lo_op2         lda screen,y
               jsr _poziomazapora
               lda screen,y
               jsr _dzialka
               lda screen,y
               jsr _pociski
               lda screen,y
               jsr _wlwyl
               iny
               iny
               bne lo_op2
               rts

_poziomazapora equ *

czestpradu     equ 6

               cmp #pusty
               beq _pozwl
               cmp #pozzap
               bne _wex

               lda screen-2,y
               cmp #pozpradnica
               beq _pozwyl
               cmp #pusty
               bne _wex
               lda #pusty
               jmp wyswietl

_wex           rts

_pozwyl        lda 53770
               cmp #czestpradu
               bcs _wex
               lda #pusty
               jmp wyswietl

_pozwl         lda screen-2,y
               cmp #pozpradnica
               beq _poz2wl
               cmp #pozzap
               bne _wex

               lda #pozzap
               jmp wyswietl

_poz2wl        lda 53770
               cmp #czestpradu
               bcs _wex
               lda #pozzap
               jmp wyswietl

*obsluga ruchu pociskow

_pociski       equ *

               cmp #52
               beq _poc2p
               cmp #54
               beq _poc1p
               cmp #58
               beq _pocl1
               cmp #56
               beq _pocl2
               cmp #68
               beq _poc3p
               cmp #poclw3
               beq _poc3l

               pha
               lda kieszen+6
               beq *+4
               pla
               rts

               pla
               cmp #70
               beq _poc3g
               cmp #60
               beq _poc1g
               cmp #62
               beq _poc2g
               rts

_poc3g         lda #60
               jmp wyswietl
_poc1g         lda #62
               jmp wyswietl

_poc3p         lda #prkraj
               jmp wyswietl

_poc2p         lda #54
               jmp wyswietl

_poc1p         lda #pusty
               jsr wyswietl
               lda screen+2,y
               cmp #pusty
               beq _pop21
               cmp #prkraj
               beq _pop22
               rts

_pop22         iny
               iny
               lda #68
               jmp wyswietl

_pop21         iny
               iny
               lda #52
               jmp wyswietl

_pocl1         lda #56
               jmp wyswietl

_pocl2         lda #pusty
               jsr wyswietl
               lda screen-2,y
               cmp #pusty
               beq _pol21
               cmp #lwkraj
               beq _pol22
               rts
_pol21         lda #58
               sta screen-2,y
               ora #1
               sta screen-1,y
               rts

_poc3l         lda #lwkraj
               jmp wyswietl

_pol22         lda #poclw3
               sta screen-2,y
               ora #1
               sta screen-1,y
               rts

_poc2g         lda #pusty
               jsr wyswietl
               lda screen+32,y
               cmp #pusty
               beq _pog22
               rts
_pog22         lda #70
               sta screen+32,y
               ora #1
               sta screen+33,y
               rts



* obsluga wystrzelenia naboju
* z dzialek                  

_dzialka       equ *

               cmp #50
               beq _lewd
               cmp #48
               beq _prawd
               pha
               lda kieszen+6
               beq *+4
               pla
               rts
               pla
               cmp #64
               beq _gordzi
               rts

_lewd          equ *

               lda screen-2,y
               cmp #pusty
               beq *+3
               rts
               lda 53770
               cmp #5
               bcs *-6
               lda #58
               sta screen-2,y
               ora #1
               sta screen-1,y

               lda zwolnij+4
               bne *+11
               lda #$20
               ldx #30
               ldy #13
               jsr m_init

               rts

_prawd         equ *

               lda screen+2,y
               cmp #pusty
               beq *+3
               rts
               lda 53770
               cmp #10
               bcs *-6
               lda #52
               iny
               iny
               jsr wyswietl

               lda zwolnij+4
               bne *+11
               lda #$20
               ldx #30
               ldy #13
               jsr m_init
               rts

_gordzi        equ *

               lda screen+32,y
               cmp #pusty
               beq *+3
               rts
               lda 53770
               cmp #10
               bcs *-6
               lda #70
               sta screen+32,y
               ora #1
               sta screen+33,y

               lda zwolnij+4
               bne *+11
               lda #$20
               ldx #30
               ldy #13
               jsr m_init
               rts

* koniec

*procedury obslugi zapory elektrycznej
*poziomej


_wlwyl         equ *

               cmp #zapora
               beq _wylacz
               cmp kieszen+7
               bne _wlwex

               lda screen-32,y
               cmp #pradnica
               beq _prad
               cmp #zapora
               bne _wlwex
               lda #zapora
               jmp wyswietl

_prad          lda 53770
               cmp #czestpradu
               bcs _wlwex
               lda #zapora
               jmp wyswietl
_wlwex         rts

_wylacz        equ *

               lda screen-32,y
               cmp #pradnica
               beq _pradoff
               cmp kieszen+7
               bne _wlwex
               lda kieszen+7
               jmp wyswietl

_pradoff       lda 53770
               cmp #czestpradu
               bcs _wlwex
               lda kieszen+7
               jmp wyswietl


_zapora        equ *

               pha
               txa
               pha
               tya
               pha
               inc _zapkontrol
               ldy _zapkontrol
               cpy #4
               bne _zaplop
               ldy #0
               sty _zapkontrol
_zaplop        lda fzzap,y
               tay
               ldx #0
_zaplp         lda pozdan,y
               sta zapznk,x
wp2            lda poz2dan,y
               sta zapznk+1024,x
               lda pindan,y
               sta zaiznk,x
               lda pin2dan,y
               sta zaiznk+1024,x
               lda koddoor,y
               sta ldorznk,x
               lda kod2door,y
               sta ldorznk+1024,x
               lda lasdoor,y
               sta lasznk,x
               sta lasznk+1024,x
               lda 53770
               and #%01010101
               sta telp,x
               lda 53770
               and #%01010101
               sta telp+1024,x

               iny
               inx
               cpx #16
               bne _zaplp
               pla
               tay
               pla
               tax
               pla
               rts


_zap_rozpoznaj equ *

     dec reals+1
     ldy #255
     lda (reals),y
     inc reals+1
     and #%00000100
     beq _s_k
     lda #0
     sta kieszen+7
     lda <kosmozap
     sta _zaplp+1
     sta wp2+1
     lda >kosmozap
     sta _zaplp+2
     sta wp2+2
     rts

_s_k lda #16
     sta kieszen+7
     lda <pozdan
     sta _zaplp+1
     lda <poz2dan
     sta wp2+1
     lda >pozdan
     sta _zaplp+2
     lda >poz2dan
     sta wp2+2
     rts

               icl 'ATP_CD'
               icl 'D:DANE_ATP.ASM'
               icl 'D:SPRITE2'
               icl 'D:BOHATER.ASM'
               icl 'D:AIR_FIR4.ASM'
               icl 'D:DANE3.ASM'
               icl 'D:DANE5_SP'
               icl 'D:GAMEFONT.ASM'
               icl 'INFOFONT'

               org $8500

fuel           equ *

     dta b(0),b(39),b(159),b(124),b(255),b(255),b(245),b(247)
     dta b(0),b(192),b(240),b(60),b(12),b(204),b(124),b(252)
     dta b(245),b(247),b(247),b(247),b(254),b(251),b(46),b(0)
     dta b(248),b(252),b(232),b(184),b(236),b(232),b(160),b(0)

micro          equ *

     dta b(165),b(165),b(64),b(15),b(63),b(14),b(14),b(58)
     dta b(80),b(84),b(0),b(224),b(172),b(160),b(160),b(172)
     dta b(10),b(10),b(58),b(10),b(10),b(58),b(10),b(2)
     dta b(160),b(160),b(172),b(160),b(160),b(172),b(160)
     dta b(128)

bron           equ *

     dta b(165),b(165),b(1),b(32),b(255),b(254),b(234),b(0)
     dta b(80),b(84),b(64),b(4),b(214),b(106),b(170),b(170)
     dta b(80),b(84),b(80),b(68),b(16),b(68),b(16),b(0)
     dta b(42),b(42),b(42),b(42),b(42),b(72),b(16),b(0)

dysk           equ *
     dta b(0),b(255),b(238),b(238),b(255),b(170),b(164),b(160)
     dta b(0),b(232),b(232),b(228),b(232),b(168),b(104),b(40)
     dta b(164),b(169),b(168),b(168),b(168),b(170),b(0),b(0)
     dta b(104),b(136),b(168),b(168),b(168),b(168),b(0),b(0)

unkill         equ *

     dta b(165),b(149),b(85),b(85),b(80),b(1),b(81),b(114)
     dta b(80),b(84),b(80),b(68),b(16),b(0),b(20),b(52)
     dta b(2),b(3),b(111),b(3),b(2),b(114),b(81),b(1)
     dta d'  ',b(228),d'  ',b(52),b(20),b(0)

supra          equ *

     dta b(164),b(148),b(84),b(80),b(67),b(8),b(60),b(250)
     dta b(60),b(250),b(233),b(164),b(16),b(48),b(48),b(36)
     dta b(233),b(36),b(3),b(64),b(16),b(68),b(16),b(0)
     dta b(24),b(12),b(12),b(196),b(60),b(250),b(233),b(36)

energy         equ *

     dta b(31),b(122),b(229),b(229),b(230),b(230),b(230),b(229)
     dta b(240),b(168),b(89),b(89),b(169),b(169),b(169),b(105)
     dta b(229),b(230),b(230),b(230),b(229),b(229),b(106),b(21)
     dta b(105),b(169),b(169),b(169),b(89),b(89),b(168),b(80)

               org $2e0
               dta a(poczatek)