0 POKE 566,158:GOTO 2
1 RETURN 
2 ? "$)":FOR N=0 TO 3:SOUND N,0,0,0:NEXT N:DIM IN$(15),OUT$(15),MP$(7684),MI$(7960),A$(5)
3 MI$(1)=" ":MI$(7960)=MI$:MI$(2)=MI$:MP$=MI$:IO=848:A$="     ":MAX=10
4 AD=ADR(MP$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
5 FOR X=1 TO 500:NEXT X:FLG=0
6 TRAP 6:GRAPHICS 0:POKE 710,26:POKE 709,2:GOSUB 50:? :? "Podaj typ pliku  ";:INPUT SRC
7 SETCOLOR 2,SRC,10:FLG=SRC=5
8 IF SRC=0 THEN GOSUB 35:GOTO 6
9 IF SRC>MAX OR SRC<0 THEN 6
10 ? :? "Nazwa pliku";:INPUT IN$:GOSUB 1
11 IF LEN(IN$)<2 THEN GOSUB 35:GOTO 10
12 TRAP 12:GOSUB 50:POKE 710,102:POKE 709,0:? :? "Podaj typ pliku wyjsciwego";:INPUT DEST
13 SETCOLOR 2,DEST,10:GOSUB 1:FLG=DEST=5
14 IF DEST=0 THEN GOSUB 35:GOTO 12
15 IF DEST>MAX OR DEST<0 THEN 12
16 ? :? "Nazwa pliku";:INPUT OUT$
17 IF LEN(OUT$)<2 THEN GOSUB 35:GOTO 16
18 IF  NOT (DEST=7 AND OUT$(LEN(OUT$)-3,LEN(OUT$))<>".BKG") THEN 20
19 ? :? "Gdzie extender .BKG !!!":FOR X=1 TO 150:NEXT X:GOTO 16
20 IF  NOT ((DEST=4 OR DEST=5) AND OUT$(LEN(OUT$)-3,LEN(OUT$))<>".PIC") THEN 22
21 ? :? "Gdzie extender .PIC !!!":FOR X=1 TO 150:NEXT X:GOTO 16
22 IF  NOT (DEST=10 AND OUT$(LEN(OUT$)-3,LEN(OUT$))<>".SCR") THEN 24
23 ? :? "Gdzie extender .SCR !!!":FOR X=1 TO 150:NEXT X:GOTO 16
24 GRAPHICS 0:GOSUB 1:? :? "Wsun dysk wejsciowy, nacisnij  START "
25 IF PEEK(53279)<>6 THEN 25
26 IF SRC=5 THEN POKE 4226,40:POKE 4229,2:REM RESTON
27 TRAP 6:CLOSE #1:OPEN #1,4,0,IN$:CLOSE #1:TRAP 40000
28 ON SRC GOSUB 96,75,101,178,177,130,142,96,164,96
29 IF SRC=10 THEN MP$(7681,7684)="    "
30 GRAPHICS 0:GOSUB 1:POKE 710,66:POKE 709,12:? :? :? :? "Wsun dysk wyjsciowy,nacisnij  START $)"
31 IF PEEK(53279)<>6 THEN POKE 712,PEEK(20):GOTO 31
32 GOSUB 1:TRAP 40000
33 ON DEST GOSUB 71,55,112,192,191,123,152,161,169,203
34 CLR :GOTO 2
35 ? "$)            .Directory.":? 
36 REM DISK DIRECTORY
37 REM 
38 CLOSE #1:OPEN #1,6,0,"D:*.*":FL=0
39 INPUT #1,IN$
40 TRAP 44
41 ? "     ";IN$(1,13);
42 IF FL THEN ? 
43 FL= NOT FL:GOTO 39
44 ? :? :? 
45 CLOSE #1
46 POKE 764,255:? :? :? "Nacisnij dowolny klawisz":? "lub RETURN dla directory"
47 OPEN #1,4,0,"K:":GET #1,FL:CLOSE #1
48 IF FL=155 THEN 35
49 POKE 764,255:POKE 4226,105:POKE 4229,1:RETURN 
50 GOSUB 1:? "$)"," (1) Micropainter":? ,"(2) Micro Illustrator/Koala"
51 ? ,"(3) Fun With Art":? ,"(4) Paint (Atari)"
52 ? ,"(5) Paint (Reston)":? ,"(6) Visualizer"
53 ? ,"(7) Moviemaker":? ,"(8) Desing Master":? ,"(9) Atarigraphics":? ,".(10) Graphics Machine"
54 RETURN 
55 MI$="        	.IG."
56 REM MP TO MI COMPRESSED
57 IF MP$(7681,7684)="    " THEN MP$(7681,7684)="    "
58 MI$(18,18)=MP$(7681,7681):MI$(14,16)=MP$(7682,7684):MI$(17,17)="."
59 MI$(19,20)="W."
60 RESTORE 62:FOR X=21 TO 28:READ A
61 MI$(X,X)=CHR$(A):NEXT X
62 DATA 0,0,155,155,155,155,162,255
63 FOR COUNT=1 TO 60
64 A=COUNT*128-99:B=COUNT*127-126
65 MI$(A,A+126)=MP$(B,B+126):MI$(A+127,A+127)=CHR$(255)
66 NEXT COUNT
67 MI$(7708,7708)=CHR$(188)
68 MI$(7709)=MP$(7621,7680)
69 TRAP 50:OPEN #1,8,0,OUT$:? #1;MI$;
70 CLOSE #1:RETURN 
71 TRAP 50:CLOSE #1:OPEN #1,8,0,OUT$
72 REM KEEP AN MP FILE
73 ? #1;MP$;:CLOSE #1
74 RETURN 
75 DIM MAIN$(342)
76 REM LOAD AN MI PICTURE
77 RESTORE 81
78 FOR A=1536 TO 1556
79 READ B:POKE A,B
80 NEXT A
81 DATA 162,16,169,1,157,72,3,169,0,157,73,3,32,86,228,48,1,96,104,104,96
82 MAIN$="                                        h".)..B.)h.D.)"
83 MAIN$(55)="                                             %h.j..t%h.D.f. "
84 MAIN$(115)="                                              f%X...d%Y.a.e "
85 MAIN$(175)="                          .%h.i../Fb)	EbPuFc)	EcPmp7 "
86 MAIN$(228)=CHR$(155)
87 MAIN$(229)="                                                  .).EjpRpI%i "
88 MAIN$(291)="                                      a...fl.)(ed..)"
89 POKE 88,ADLO:POKE 89,ADHI
90 OPEN #1,4,0,IN$:POKE 559,0
91 A=USR(ADR(MAIN$))
92 MP$(7681,7681)=CHR$(PEEK(712))
93 FOR X=0 TO 2:MP$(X+7682,X+7682)=CHR$(PEEK(708+X)):NEXT X
94 CLOSE #1:GRAPHICS 0:POKE 559,34
95 GOSUB 1:RETURN 
96 CLOSE #1:OPEN #1,4,0,IN$
97 REM GET A MP/GM FILE
98 POKE IO+2,7:POKE IO+4,ADLO:POKE IO+5,ADHI:POKE IO+8,4:POKE IO+9,30
99 JNK=USR(ADR("hhh*LVd"),16):CLOSE #1
100 RETURN 
101 IO=848:OPEN #1,4,0,IN$
102 REM FWA to MP
103 AD=ADR(MI$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
104 POKE IO+2,7:POKE IO+4,ADLO:POKE IO+5,ADHI
105 POKE IO+8,24:POKE IO+9,31
106 N=USR(ADR("hhh*LVd"),16)
107 CLOSE #1
108 MP$(1,4080)=MI$(263,4342)
109 MP$(4081,7680)=MI$(4359,7958)
110 MP$(7681,7684)=MI$(3,6)
111 RETURN 
112 MI$=" ":MI$(1)=" ":MI$(7960)=MI$:MI$(2)=MI$
113 REM MP to FWA
114 MI$(1,65)="                                                               $-$-"
115 MI$(66,132)="                  ................................................N"
116 MI$(133,200)="...................................................................."
117 MI$(201,262)="                                                        .....A"
118 MI$(263,4342)=MP$(1,4080)
119 MI$(4359,7958)=MP$(4081,7680)
120 MI$(7959,7960)="  "
121 MI$(3,6)=MP$(7681,7684)
122 TRAP 50:OPEN #1,8,0,OUT$:? #1;MI$(1,7960);:CLOSE #1:RETURN 
123 REM MP TO VIS
124 MI$=" "
125 MI$(1,3)=MP$(7682,7684):MI$(4,4)=" ":MI$(5,5)=MP$(7681,7681)
126 CNT=7
127 FOR I=1 TO 166 STEP 2
128 MI$(CNT,CNT+39)=MP$(I*40-39,I*40):CNT=CNT+40:NEXT I
129 TRAP 50:OPEN #1,8,0,OUT$:? #1;MI$(1,3326);:CLOSE #1:RETURN 
130 REM VIS TO MP
131 AD=ADR(MI$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
132 OPEN #1,4,0,IN$
133 POKE IO+2,7:POKE IO+4,ADLO:POKE IO+5,ADHI:POKE IO+8,254:POKE IO+9,12
134 U=USR(ADR("hhh*LVd"),16):CLOSE #1
135 CNT=7
136 MP$(7682,7684)=MI$(1,3):MP$(7681,7681)=MI$(4,4)
137 FOR I=0 TO 190 STEP 2
138 MP$(I*40+1,I*40+40)=MI$(CNT,CNT+39)
139 MP$(I*40+41,I*40+80)=MI$(CNT,CNT+39)
140 CNT=CNT+40:NEXT I
141 RETURN 
142 REM MM TO MP
143 AD=ADR(MI$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
144 CLOSE #1:OPEN #1,4,0,IN$
145 POKE IO+2,7:POKE IO+4,ADLO:POKE IO+5,ADHI:POKE IO+8,16:POKE IO+9,15
146 JNK=USR(ADR("hhh*LVd"),16):CLOSE #1
147 FOR X=1 TO 3840 STEP 40
148 NN=2*X-1:MP$(NN,NN+39)=MI$(X,X+39):MP$(NN+40,NN+79)=MI$(X,X+39)
149 NEXT X
150 MP$(7681,7684)=MI$(3841,3844)
151 RETURN 
152 REM MP TO MM
153 MI$(1)=" ":MI$(3856)=MI$:MI$(2)=MI$
154 FOR X=41 TO 7680 STEP 160
155 NN=X/2-19.5
156 MI$(NN,NN+79)=MP$(X,X+79)
157 NEXT X
158 MI$(3841,3844)=MP$(7681,7684)
159 TRAP 50:OPEN #1,8,0,OUT$:? #1;MI$(1,3856);:CLOSE #1
160 RETURN 
161 REM MP TO GM
162 TRAP 50:CLOSE #1:OPEN #1,8,0,OUT$
163 ? #1;MP$;" ";:CLOSE #1:RETURN 
164 REM AG TO MP
165 GOSUB 96
166 MI$=" ":MI$(1,1)=MP$(7684,7684):MI$(2,4)=MP$(7681,7683)
167 MP$(7681,7684)=MI$
168 RETURN 
169 REM MP TO AG
170 MI$=" ":MI$(4,4)=MP$(7681,7681):MI$(1,3)=MP$(7682,7684)
171 MP$(7681,7684)=MI$
172 TRAP 50:CLOSE #1:OPEN #1,8,0,OUT$
173 ? #1;MP$;
174 MP$(1)=" ":MP$(7684)=MP$:MP$(2)=MP$
175 ? #1;MP$;MP$(1,504);:CLOSE #1
176 RETURN 
177 POKE 4226,40:POKE 4229,2:REM RESTON
178 REM PAINT TO MP
179 AD=ADR(MI$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
180 CLOSE #1:OPEN #1,4,0,IN$
181 POKE IO+2,7:POKE IO+4,ADLO:POKE IO+5,ADHI:POKE IO+8,144:POKE IO+9,12
182 JNK=USR(ADR("hhh*LVd"),16):CLOSE #1
183 A$=MI$(1,4)
184 MP$(1,3200)=MI$(17,3216):MI$=" ":MI$=MP$(1,3200)
185 FOR X=1 TO 3200 STEP 40
186 NN=2*X-1:MP$(NN,NN+39)=MI$(X,X+39):MP$(NN+40,NN+79)=MI$(X,X+39)
187 NEXT X
188 MP$(7681,7684)=A$(1,4)
189 POKE 4226,105:POKE 4229,1
190 RETURN 
191 POKE 4226,40:POKE 4229,2:REM RESTON
192 REM MP TO PAINT
193 MI$(1)=" ":MI$(3216)=MI$:MI$(2)=MI$
194 A$=MP$(7681,7684)
195 FOR X=41 TO 6281 STEP 160
196 NN=X/2-19.5
197 MI$(NN,NN+79)=MP$(X,X+79)
198 NEXT X
199 MP$=MI$:MI$=A$:MI$(6,16)="@1(D(3(p0nH":MI$(17)=MP$
200 TRAP 50:OPEN #1,8,0,OUT$:? #1;MI$(1,3216);:CLOSE #1
201 POKE 4226,105:POKE 4229,1
202 RETURN 
203 TRAP 50:CLOSE #1:OPEN #1,8,0,OUT$
204 ? #1;MP$(1,7680);:CLOSE #1:RETURN 
----------- end of file -----------