*KERNEL EXAMPLE - MULTICOLORED PLAYER -MOVES WITH JOYSTICK
*CODED BY DAN PINAL
PDATA	EQU	$6000
PMBASE	EQU	$D407
SDLSTL	EQU	$230
HPOSP0	EQU	$D000
PCOLR0	EQU	$2C0
COLPM0	EQU	$D012
WSYNC	EQU	$D40A
VCOUNT	EQU	$D40B
IRQEN	EQU	$D20E
NMIEN	EQU	$D40E
VDSLST	EQU	$200
VVBLKD	EQU	$224
SDMCTL	EQU	$22F
DMACTL	EQU	$D400
GRACTL	EQU	$D01D
SETVBV	EQU	$E45C
XITVBV	EQU	$E462
MISSL0	EQU	PDATA+$300
PLAYR0	EQU	MISSL0+$100
PLAYR1	EQU	PLAYR0+$100
PLAYR2	EQU	PLAYR1+$100
PLAYR3	EQU	PLAYR2+$100
STICK0	EQU	$278
*ZERO PAGE EQUATES
VTEMP0	EQU	$F0
VTEMP1	EQU	$F1
P0TMP0	EQU	$F8
P0TMP1	EQU	$F9
	ORG	$4000
INIT
	LDA	#>DLIST
	STA	SDLSTL
	LDA	#<DLIST
	STA	SDLSTL+1
	LDA	#>KERNEL	; SET DISPLAY LIST INTERRUPT
	STA	VDSLST
	LDA	#<KERNEL
	STA	VDSLST+1
	LDY	#>VBLANK	; SET VERTICAL BLANK
	LDX	#<VBLANK
	LDA	#$07		; DEFFERRED
	JSR	SETVBV
	LDA	#<PDATA		; INIT PM GRAPHICS
	STA	PMBASE
	LDA	#$3E
	STA	SDMCTL
	LDA	#03
	STA	GRACTL
	LDA	#<MISSL0	; CLEAR PLAYER/MISSILE RAM
	STA	P0TMP1
	LDA	#00
	STA	P0TMP0
	TAY
	LDX	#05		; 5 PAGES
CLEARP
	STA	(P0TMP0),Y
	INY
	BNE	CLEARP
	INC	P0TMP1
	DEX
	BNE	CLEARP
	LDA	#$0E		; WHITE
	STA	PCOLR0
	LDA	#$80
	STA	PLAYRH
	STA	PLAYRV
; ENABLE	; INTERRUPTS
	LDA	#$C0
	STA	NMIEN
HERE
	JMP	HERE		; ENDLESS LOOP OUTSIDE VBLANK
*VBLANK ROUTINE
VBLANK
	LDA	#$C0
	STA	NMIEN		; REENABLE DLI (FOR REV. A O.S.)
	LDX	STICK0		; JOYSTICK0 VALUE
	CLC
	LDA	PLAYRH		; LOAD OLD HORIZ. PLAYER POS
	ADC	HOFF,X		; ADD HORIZ DIRECTION VECTOR
	CMP	#$30
* CHECK IF PAST RIGHT OR LEFT EDGE
	BCC	NEWV
	CMP	#$D0
	BCS	NEWV
	STA	PLAYRH		;STORE NEW HORIZ PLAYER POSITION
	STA	HPOSP0		;TELL ANTIC
NEWV
	CLC
	LDA	PLAYRV		;LOAD OLD VERT PLAYER POS
	ADC	VOFF,X		;ADD VERT DIRECTION VECTOR
* CHECK IF PAST TOP OR BOTTOM
	CMP	#$22
	BCC	XVBLANK
	CMP	#$D0
	BCS	XVBLANK
	STA	PLAYRV		;STORE NEW VERT POSITION
	STA	VTEMP0		;LO BYTE OF P/M AREA
	LDA	#<PLAYR0
	STA	VTEMP1		;HI BYTE OF P/M AREA
	LDY	#$13		;20 ELEMENTS
PDRAW
	LDA	IMAGE,Y		;GET BYTE FROM SHAPE TABLE
	STA	(VTEMP0),Y	;STORE BYTE IN P/M AREA
	DEY			;NEXT BYTE
	BPL	PDRAW		;DONE?
XVBLANK
	JMP	XITVBV
*
KERNEL
	PHA			; SAVE REGISTERS
	TXA
	PHA
	TYA
	PHA
	LDX	#$03		; USE X FOR INDEX To COLOR TABLE
	LDA	PLAYRV		; GET VERT. POS.
	LSR			; VCOUNT COUNTS EVERY OTHER LINE
	TAY
	INY
UNTIL
	STA	WSYNC		;WAIT TILL OFF SCREEN
	CPY	VCOUNT		;ARE WE AT LINE TO BFGIN CHANGING
	BCS	UNTIL		;NO HAVEN'T REACHED IT-BRANCH
CHANGE
	LDA	COLOR,X		; GET COLOR
	STA	COLPM0		; STUFF COLOR
	STA	WSYNC		; WAIT 3 LINES # DO NEXT CHANGE
	STA	WSYNC
	STA	WSYNC
	DEX
	BPL	CHANGE		; GO BACK TILL ALL CHANGES MADE
	JMP	XITVBV		; LET O.S. RESTORE REGISTERS
IMAGE	DB	$00,$00,$10,$10,$10,$10,$38,$38
	DB	$38,$38,$7C,$7C,$7C,$FE,$FE,$54
	DB	$54,$00,$00
HOFF	DB	$00,$00,$00,$00,$00,$02,$02,$02
	DB	$00,$FE,$FE,$FE,$00,$00,$00,$00
VOFF	DB	$00,$00,$00,$00,$00,$02,$FE,$00
	DB	$00,$02,$FE,$00,$00,$02,$FE,$00
COLOR	DB	$44,$76,$B8,$3A
DLIST	DB	$80,$41
*	DA DLIST
	DW	DLIST
PLAYRH	DB	$00
PLAYRV	DB	$00