org $480
               opt %10101

max1           equ 6
max2           equ 10
max3           equ 14
summax         equ max1+max2+max3

text           equ $f0

               lda #$90
               sta 756

               ldx #0
rloop          lda 53770
               sta kosmotable,x
               inx
               cpx #93
               bne rloop
               lda #0
               sta kosmotable+94

               lda <wystext
               sta text
               lda >wystext
               sta text+1


               lda <display
               sta 560
               lda >display
               sta 561
               lda <nmi
               sta 552
               lda >nmi
               sta 553
               lda #61
               sta 559
               lda #1
               sta 538
               lda <dli
               sta 512
               lda >dli
               sta 513
               lda #192
               sta 54286
               lda #3
               sta 53277
               lda #$f0
               sta 54279
               lda #15
               sta 704
               lda #64
               sta txtcounter
               rts


nmi            equ *

               lda #1
               sta 538

               ldx #0
nloop          inc kosmotable,x
               inc kosmotable+1,x
               inc kosmotable+1,x
               inx
               inx
               cpx #94
               bne nloop
               ldx #0
n2loop         inc kosmotable,x
               inc kosmotable,x
               txa
               clc
               adc #5
               tax
               cpx #90
               bne n2loop

               jsr __scrol

               inc tmp
               lda tmp
               cmp tempo
               beq nmi2
               rts
nmi2           lda #0
               sta tmp

               lda txtcounter
               bne _clear
               lda #4
               sta tempo
               lda color1
               cmp #max1
               beq _col2
               inc color1
_col2          lda color2
               cmp #max2
               beq _col3
               inc color2
_col3          lda color3
               cmp #max3
               beq _col4
               inc color3
_col4          lda color1
               clc
               adc color2
               clc
               adc color3
               cmp #summax
               bne _col5
               lda #60
               sta tempo
               lda #64
               sta txtcounter
_col5          rts
_clear         ldx txtcounter
               lda #0
               sta filmtext,x
               dec txtcounter
               lda #1
               sta tempo
               lda txtcounter
               bne _c3
               lda color1
               ora color2
               ora color3
               beq nap
               inc txtcounter
               ldy #0
               sty color1
               sty color2
               sty color3
               rts
nap            ldy #0
napisz         lda (text),y
               sta filmtext,y
               iny
               cpy #64
               bne napisz
               lda text
               clc
               adc #64
               sta text
               bcc _c2
               inc text+1
_c2            lda text
               cmp <koniecwyswietlania
               bne _c4
               lda text+1
               cmp >koniecwyswietlanie
               bne _c4
               lda <wystext
               sta text
               lda >wystext
               sta text+1
_c4            lda #30
               sta tempo
_c3            rts

__scrol        equ *

               lda scrol
               beq skok
               dec scrol
               rts
skok           inc mlodszy
               lda mlodszy
               cmp <endek
               bne *+7
               lda <sctext
               sta mlodszy
skok2          lda #7
               sta scrol
               rts


dli            equ *

               pha
               txa
               pha

               ldx #0
d0loop         lda kosmotable,x
               sta 54282
               sta 53252
               lda #6
               sta 53270
               lda #10
               sta 53271
               lda #15
               sta 53272
               inx
               cpx #95
               bne d0loop
               lda <dli1
               sta 512
               lda >dli1
               sta 513
               pla
               tax
               pla
               rti
dli1           equ *

               pha
               txa
               pha

               ldx #0
dloop          lda tecza,x
               sta 54282
               sta 53274
               inx
               cpx #14
               bne dloop
               lda <dli2
               sta 512
               lda >dli2
               sta 513
               pla
               tax
               pla
               rti

dli2           equ *

               pha

               lda color1
               sta 53270
               lda color2
               sta 53271
               lda color3
               sta 53272
               lda <dli3
               sta 512
               lda >dli3
               sta 513

               pla
               rti

dli3           equ *

               pha
               txa
               pha

               lda scrol
               sta 54276
               lda mlodszy
               sta scadr
               lda starszy
               sta scadr+1

               ldx #0
d3loop         lda rura,x
               sta 54282
               sta 54282
               sta 53270
               ora #2
               sta 53272
               inx
               cpx #4
               bne d3loop

               lda <dli
               sta 512
               lda >dli
               sta 513

               pla
               tax
               pla
               rti



               org $a000

scrol          dta b(0)
mlodszy        dta l(sctext)
starszy        dta h(sctext)
color1         dta b(0)
color2         dta b(0)
color3         dta b(0)


display        equ *

          dta d'p',b(240)
          dta b(64+5),a(txt)
          dta d'pp',b(4),d'p',b(4),d'p',b(4)
          dta d'p',b(4)
          dta b(240)
          dta d'pp',b(240)
          dta b(64+4),a(filmtext)
          dta d'p',b(4),d'pp',b(240)
          dta b(64+6+16)
scadr     dta a(sctext)
          dta b(65),a(display)

tecza          dta b(2),b(4),b(6),b(8),b(10),b(12),b(14)
               dta b(12),b(10),b(8),b(6),b(4),b(2),b(0)
rura           dta b(6),b(8),b(12),b(8),b(4),b(0)


txtcounter     dta b(0)
tempo          dta b(1)
tmp            dta b(0)


filmtext       equ *

     dta d'                                '
     dta d'                                '

wystext        equ *

     dta d'            PROGRAM:            '
     dta d'          JANUSZ GRZYB          '
     dta d'            GRAFIKA:            '
     dta d'          JANUSZ GRZYB          '
     dta d'             MUZYKA:            '
     dta d'          JANUSZ GRZYB          '
     dta d'          DYSTRYBUCJA:          '
     dta d'           L.K AVALON           '
koniecwys      equ *

txt            equ *

     dta d'       AROUND THE PLANET        '
     dta d'   START  ...  ROZPOCZ.CIE GRY  '
     dta d'   SELECT ...  MUZYKA  LUB FX   '
     dta d'   OPTION ...  KOLOR LUB MONO   '
     dta d'   ESCAPE ...  PRZERWANIE GRY   '

kosmotable     dta d'                         '
               dta d'                         '
               dta d'                         '
               dta d'                         '

               org $8500

sctext         equ *


               dta d'                '
               dta d'... AROUND THE PLANET ...         '
               dta d'     AUTOR:  JANUSZ GRZYB            '
               dta d'      DYSTRYBUCJA: L.K.AVALON  '
               dta d'  '
endek          equ *