10 REM Simple Checkbook Program
11 REM JHS 06/08/86 Version 1.0
12 REM Command interpreter to be
13 REM added in later version.
15 DIM A$(40):TRAP 200:BAL=0
200 REM Startup Routines
220 DIM C(100):DIM D(300)
1000 REM F - Forward Balance
1005 TRAP 2000
1010 ? "Balance forward from prev stmt":INPUT BALF:BAL=BALF
2000 REM C - Enter Credit Items
2010 ? "Enter credit items (deposits,":? "interest, corrections etc.),"
2020 ? "followed by RETURN, or just RETURN":? "to end input.":NC=0
2030 FOR I=1 TO 100:INPUT A$:IF LEN(A$)=0 THEN GOTO 3000
2035 C(I)=VAL(A$)
2040 BAL=BAL+C(I):NC=I:NEXT I
3000 REM D - Debits: checks & charges
3010 ? "Enter debits(checks&charges)"
3020 ? "Start with checks, beginning with":? "check number";:NCHK=0
3025 TRAP 3030:INPUT A$:NCHK=VAL(A$):ND=0
3030 FOR I=1 TO 300:? NCHK;"  ";:INPUT A$:IF LEN(A$)=0 THEN GOTO 4000
3040 D(I)=VAL(A$):BAL=BAL-D(I)
3050 ND=I:IF D(I)>=0 THEN NCHK=NCHK+1
3060 IF D(I)<0 THEN NCHK=NCHK-1
3070 NEXT I
4000 REM Final Output Section
4010 TC=0:TD=0
4020 IF NC>0 THEN FOR I=1 TO NC:TC=TC+C(I):NEXT I
4030 IF ND>0 THEN FOR I=1 TO ND:TD=TD+D(I):NEXT I
4090 ? "STARTING BALANCE WAS $";BALF
4100 ? "TOTAL CREDITS $";TC;"    # ITEMS: ";NC
4101 ? "TOTAL DEBITS $";TD;"    # ITEMS: ";ND
4102 ? "ENDING BALANCE IS $";BAL:? :?
4110 ? "DO NEXT MONTH";:INPUT A$:IF A$(1,1)="Y" THEN BALF=BAL:GOTO 2000:END